FFmpeg mehrere Dateien zusammenführen automatisieren

Heißen die Dateien immer gleich?
Und welches System nutzt du?

System wollte ich nur wissen damit ich weiß wofür das ist.

@echo off
set zaehler=0
Setlocal EnableDelayedExpansion
for /r "%cd%" %%i in ("Folge"*"VIDEO"*".mp4") do (
set /A zaehler=zaehler+1
if  !zaehler! LSS 10 echo start /wait ffmpeg -i "%%i" -i "Folge 0!zaehler!_AUDIO_audio-stereo-hi.mp4" -c copy E0!zaehler!.mp4 
if  !zaehler! GEQ 10 echo start /wait ffmpeg -i "%%i" -i "Folge !zaehler!_AUDIO_audio-stereo-hi.mp4" -c copy E!zaehler!.mp4
)
pause

Das kommt in eine batch Datei im selben Verzeichnis. und wird ausgeführt.
Im Moment sind in den if Angaben noch echo angaben so das du erstmal prüfen kannst was da ausgeführt wird.
ffmpeg muss da im selben verzeichnis sein oder "global" aufgerufen werden können.

Eine Warnung noch - im Moment ist das recursiv - also alle Unterverzeichnisse werden auch betroffen.
Und ganz wichtig: es funktioniert nur wenn alle Folgen ausnahmslos da sind.

Ach LOL und ich hab mir da Gedanken gemacht wegen der führenden Null. So hast du jetzt manämlich das "Phänomen" das es beim listen im Explorer verkehrt ist.
Deshalb sind es ja 2 Reihen. Aber du hast Recht, ich hätte mir das Listing vorher nochmal angucken müssen.
Das mit dem " zuviel ... naja ok Künstlerpech deshalb sag ich ja vorher angucken.

@fireb
hm, let's try...

@echo off
Setlocal EnableDelayedExpansion
for /r %%i in (*"VIDEO"*.mp4) do (
for /f "delims=_ tokens=1" %%f in ("%%~ni") do (
echo start /wait ffmpeg -i "%%i" -i "%cd%\%%f_AUDIO_audio-stereo-hi.mp4" -c copy "%%f.mp4"
)
)

Wieder mit echo, first schauen obs gut wird oder nicht.

Kleiner Input am Rande, wenn du für sowas andere Dateiänderungen nutzt (z.b. mpv und mpa) wäre die batch einfacher zu bewerkstelligen. So machst du es dir nur selbst schwer

Kleines Beispiel

for %%f in (*.mpv) do (
blabladeincommand
)

@quorn23
Erzähl bitte mal ein bissl mehr.
Wie ich nur die Dateien mit der Endung raussortier ist schon klar.
Nur wüsste ich nicht wie das in diesem speziellen fall hilft.

Um das Script mal auseinander zu nehmen
@echo off man sieht die Eingaben nicht mehr.
Setlocal EnableDelayedExpansion Sorgt dafür das ich die Variablen in der Batch weiter nutzen kann
for /r %%i in (*"VIDEO"*.mp4) do ( öffnet eine Schleife und sucht nach den Dateien im aktuellen Verzeichnis mit dem String Video drin und der Endung .mp4 - wird gespeichert in der Variable %i
for /f "delims=_ tokens=1" %%f in ("%%~ni") do ( Sucht in der Variable i ohne die Endung nach dem Vorkommen von _ und teilt das in diesem Fall nur nach dem ersten vorkommen - wird gespeichert in der Variable %f
echo start /wait ffmpeg -i "%%i" -i "%cd%\%%f_AUDIO_audio-stereo-hi.mp4" -c copy "%%f.mp4" gibt solange das echo drin ist den Befehl aus der die Video Datei %i mit der Datei %f - mit Audiostring im aktuellen Verzeichnis %cd% in der Datei %f gemerged wird.
)) schließt beide Schleifen.

Das ist halt auf das spezielle zweite Beispiel des TO gemünzt.
Wie hättest Du das gemacht?

Hi @SkyBird1980

Der Input war eher an den OT gerichtet, nicht an dich.
Mit deiner Batchdatei ist nichts verkehrt, was ich in diesem speziellen Fall anders gemacht hätte.
Finde es grosse Klasse, dass du deinen Ablauf auseinander genommen hast, falls jemand mit so etwas Hilfe benötigt.
Da mein Input in kurz "Nutzt klare Dateiendungen, damit macht ihr Euch das Leben einfacher" ist, denke ich ist deine Frage an mich damit beantwortet.
Bisschen detailierter, ich hätte kurzerhand die Dateien unbenennt, damits in ne einfache Schlaufe passt. (Tipp für die Mitleser, unter Windows ruckzuck mit "AntRenamer")

Als Beispiel, welches ich auf dem Windowsrechner im Einsatz habe, für Animationen gibt es den Yuuki x265 custom build, welche ich hin und wieder für Gedöns wie Family Guy und co nutze, da die Dateigrösse vs Qualität absolut wunderbar ist, ohne mit Konvertierungssettings zu feilen. Dieser konvertieret bloss Video, daher zerpflücke ich das File erst in Video/Audio, konvertiere mit dem Build und setze mir am Schluss die Datei wieder komplett zusammen.

@echo off
IF exist Output ( echo Output exists ) ELSE ( mkdir Output && echo Output created)


for %%f in (*.MKV) do (
D:/mkvtoolnix\mkvmerge.exe --output "%%~nf.audio" --no-video --language 0:eng --default-track 0:yes --sub-charset 2:UTF-8 --language 2:und --default-track 2:yes "%%~f" --track-order 0:0,0:2
)


for %%f in (*.mkv) do (
echo "Video only" is being converted
D:/videoconvert/x265_Yuuki\x265-10bit-full.exe "%%~f" -o "%%~nf.video"
del "%%f"
)


for %%f in (*.video) do (
D:/videoconvert/mkvtoolnix\mkvmerge.exe --output "Output\%%~nf.mkv" --language 0:eng --default-track 0:yes "%%f" --language 0:eng --default-track 0:yes --sub-charset 1:UTF-8 --language 1:eng --default-track 1:yes "%%~nf.audio" --track-order 0:0,1:0,1:1
del "%%~nf.video"
del "%%~nf.audio"
)

Dies ist die "von A-Z" Batch, hoffe damit habe ich dir die Frage beantwortet, warum ich OT empfehle andere Endungen für verschiedene Dinge zu nutzen.
Auch wenns für dein Skript bloss ein "Dat passt!" ist.