Home-Videos

@echo off
setlocal enabledelayedexpansion
chcp 65001>NUL
set Dateityp=mp4
set /A Zaehler=0
for %%f in ("%~dp0*.%Dateityp%") do set /A Zaehler=Zaehler+1
echo Es ist/sind %Zaehler% Film(e) zu sortieren.
echo Ich oeffne jetzt einen Film nach dem anderen
echo und frage dann jeweils nach einem Namen dafuer,
echo den Rest kann ich alleine :-)
echo ##### los geht's #####
pause
set /A Schleife=0
for %%f in ("%~dp0*.%Dateityp%") do (
  set /A Schleife=Schleife+1
  echo ### Beginne Film !Schleife! von !Zaehler! ###
  start %%f
  if not exist %%~nf-fanart.jpg (
    %~dp0tools\mtn-200808a-win32\mtn.exe -c 1 -r 1 -i -o -fanart.jpg -w 1920 -P -t %%f
    echo.
    echo Fanart fuer Film !Schleife! erstellt!
    ) else (
    echo.
    echo Fanart fuer Film !Schleife! schon vorhanden, nicht neu erstellt
    )
  if not exist %%~nf-poster.jpg ( 
    %~dp0tools\mtn-200808a-win32\mtn.exe -c 1 -r 2 -i -o -poster.jpg -w 951 -P -t -g 7 -k 000000 %%f
    echo.
    echo Poster fuer Film !Schleife! erstellt!
    echo.
    ) else (
    echo.
    echo Poster fuer Film !Schleife! schon vorhanden, nicht neu erstellt
    echo.
    )
  set Zeit=%%~tf
  set dd=!Zeit:~0,2!
  set mm=!Zeit:~3,2!
  set yyyy=!Zeit:~6,4!
  set hh=!Zeit:~11,2!
  set min=!Zeit:~14,2!
  echo Der Film wurde am !dd!.!mm!.!yyyy! um !hh!:!min! aufgenommen
  echo.
  set /p Benennung=Wie soll der gerade gesehene Film denn heissen? 
  set NFO=%%~dpf%%~nf.nfo
  echo Alles klar, ich erstelle jetzt die nfo-Datei: 
  echo %%~nf.nfo
    echo.^<?xml version="1.0" encoding="UTF-8" standalone="yes" ?^>> !NFO!
    echo.^<movie^>>> !NFO!
    echo.    ^<title^>!yyyy!-!mm!-!dd! !Benennung!^</title^>>> !NFO!
    echo.    ^<sorttitle^>!yyyy!!mm!!dd!_!hh!!min!00^</sorttitle^>>> !NFO!
    echo.    ^<id^>-1^</id^>>> !NFO!
    echo.    ^<genre^>EigeneVideos^</genre^>>> !NFO!
    echo.    ^<set^>Eigene Videos^</set^>>> !NFO!
    echo.^</movie^>>> !NFO!
  md %%~dpf%%~nf
  move %%~dpnf* %%~dpf%%~nf\
  echo ### Film !Schleife! von !Zaehler! fertig ###
    )
pause

@echo off
setlocal enabledelayedexpansion
chcp 65001>NUL
set Dateityp=mp4
set /A Zaehler=0
echo cmd-Version 03
	rem neu in 03 - year tag hinzu
echo ##############
for %%f in ("%~dp0*.%Dateityp%") do set /A Zaehler=Zaehler+1
echo Es ist/sind %Zaehler% Film(e) zu sortieren.
echo Ich oeffne jetzt einen nach dem anderen
echo und frage dann nach einem Namen dafuer,
echo den Rest kann ich alleine :-)
echo ##### los geht's #####
pause
set /A Schleife=0
for %%f in ("%~dp0*.%Dateityp%") do (
  set /A Schleife=Schleife+1
  echo ### Beginne Film !Schleife! von !Zaehler! ###
  start %%f
  if not exist %%~nf-fanart.jpg (
    "C:\Program Files (x86)\Movie_Thumbnailer\mtn-200808a-win32\mtn.exe" -c 1 -r 1 -i -o -fanart.jpg -w 1920 -P -t %%f
    echo.
    echo Fanart fuer Film !Schleife! erstellt!
  ) else (
    echo.
    echo Fanart fuer Film !Schleife! schon vorhanden, nicht neu erstellt
  )
  if not exist %%~nf-poster.jpg ( 
    "C:\Program Files (x86)\Movie_Thumbnailer\mtn-200808a-win32\mtn.exe" -c 1 -r 2 -i -o -poster.jpg -w 951 -P -t -g 7 -k 000000 %%f
    echo.
    echo Poster fuer Film !Schleife! erstellt!
    echo.
  ) else (
    echo.
    echo Poster fuer Film !Schleife! schon vorhanden, nicht neu erstellt
    echo.
  )
  set Zeit=%%~tf
  set dd=!Zeit:~0,2!
  set mm=!Zeit:~3,2!
  set yyyy=!Zeit:~6,4!
  set hh=!Zeit:~11,2!
  set min=!Zeit:~14,2!
  echo Der Film wurde am !dd!.!mm!.!yyyy! um !hh!:!min! aufgenommen
  echo.
  echo Wie soll der gerade gesehene Film denn 
  set /p Benennung=heissen? [del = loeschen] 
  if !Benennung!==del (
    echo Film wird geloescht
    del %%~nf-fanart.jpg
    del %%~nf-poster.jpg
    del %%f
    echo ### Film !Schleife! geloescht ###
  ) else (
    echo.
    set peinlich=
    echo Ist auf dem Film etwas, was spaeter mal peinlich sein koennte und nur 
    echo von uns gesehen werden sollte? Nackig strampeln beim Wickeln oder so?
    set /p peinlich=Ja, ja, J oder j gilt als ja, alles andere ist nein: 
    if not defined peinlich set peinlich=Nein
    echo Peinlich: !peinlich!
    for %%i in (Ja ja J j) do if [%%i]==[!peinlich!] echo Video wurde als peinlich markiert
    echo.
    set NFO=%%~dpf%%~nf.nfo
    echo Alles klar, ich erstelle jetzt die nfo-Datei: 
    echo %%~nf.nfo
      echo.^<?xml version="1.0" encoding="UTF-8" standalone="yes" ?^>> !NFO!
      echo.^<movie^>>> !NFO!
      echo. ^<title^>!yyyy!-!mm!-!dd! !Benennung!^</title^>>> !NFO!
      echo. ^<sorttitle^>!yyyy!!mm!!dd!_!hh!!min!00^</sorttitle^>>> !NFO!
      echo. ^<id^>-1^</id^>>> !NFO!
      echo. ^<genre^>EigeneVideos^</genre^>>> !NFO!
      echo. ^<set^>Eigene Videos^</set^>>> !NFO!
	  echo. ^<year^>!yyyy!^</year^>>> !NFO!
      for %%i in (Ja ja J j) do if [%%i]==[!peinlich!] echo. ^<tag^>peinlich^</tag^>>> !NFO!
      echo. ^<dateadded^>!yyyy!-!mm!-!dd! !hh!:!min!:00^</dateadded^>>> !NFO!
	  echo.^</movie^>>> !NFO!
    md %%~dpf%%~nf
    move %%~dpnf* %%~dpf%%~nf\
    echo ### Film !Schleife! von !Zaehler! fertig ###
  )
)
pause